www.delphigl.de - Frustum Culling

Tutorial Nr.6 - Frustum Culling

Einleitung

Wenn man dabei ist eine 3D-Engine auf eigene Faust zu programmieren, wird man irgendwann damit konfrontiert das mit steigender Szenenkomplexität alles langsamer wird, und dies obwohl immer nur ein Teil der Umgebung sichtbar ist.
Moderne Grafikkarten besitzen einen Z-Puffer und andere Techniken um festzustellen, ob ein Pixel gesetzt wird oder nicht, aber bevor sie dies feststellen können, brauchen sie die Geometriedaten der Szene.Dann erst macht die Grafikkarte ihre Sichtbarkeitsoptimierungen und Tiefentests.
Wenn ein Objekt hinter einem anderen liegt, oder ausserhalb des Sichtbereiches ist, wird die Grafikkarte so schlau sein und dies merken.Aber selbst wenn das Objekt dann nicht gezeichnet wird, drückt es die Geschwindigkeit, da dessen Geometriedaten erstmal über den Bus zur Grafikkarte gelangen müssen.
Frustum Culling ist nun eine einfache Methode um VOR dem Senden der Geometriedaten festzustellen, ob ein Objekt im Sichtfeld liegt oder nicht.Dies spart jede Menge Bandbreite und bedeutet Arbeitsersparnis für den 3D-Beschleuniger.

In diesem Tutorial werde ich deshalb zeigen wie man Frustum Culling implementiert und nutz.Es ist wirklich wenig Arbeit, aber eine sehr effiziente Art seine Rendergeschwindigkeit drastisch zu erhöhen.

Die TFrustum Klasse

Wir werden das Frustum Culling mit Hilfe einer handlichen, TFrustum genannten Klasse implementieren um die Dinge etwas einfacher zu machen.Hier die Klassendeklaration :

TFrustum = object
   Frustum : array[0..5,0..3] of Single;
   function IsPointWithin(const pX, pY, pZ : Single) : Boolean;
   function IsBoxWithin(const pX, pY, pZ, pB, pH, pT : Single) : Boolean;
   procedure Calculate;
  end;

Das Frustum berechnen(procedure Calculate)

Zu aller Erst der wichtigste Teil der TFrustum Klasse : Die Berechnung des Selbigen.Bevor wir also feststellen könne, ob ein Objekt im Frustum liegt oder nicht, müssen wir zuerst dessen 6 Flächen berechnen.

[01]  procedure TFrustum.Calculate;
[02]  var
[03]   ProjM, ModM, Clip : array[0..15] of Single;
[04]  begin
[05]  glGetFloatv(GL_PROJECTION_MATRIX, @ProjM);
[06]  glGetFloatv(GL_MODELVIEW_MATRIX, @ModM);
[07]  Clip[ 0] := ModM[ 0]*ProjM[ 0] + ModM[ 1]*ProjM[ 4] +
                  ModM[ 2]*ProjM[ 8] + ModM[ 3]*ProjM[12];
[08]  Clip[ 1] := ModM[ 0]*ProjM[ 1] + ModM[ 1]*ProjM[ 5] +
                  ModM[ 2]*ProjM[ 9] + ModM[ 3]*ProjM[13];
[09]  Clip[ 2] := ModM[ 0]*ProjM[ 2] + ModM[ 1]*ProjM[ 6] +
                  ModM[ 2]*ProjM[10] + ModM[ 3]*ProjM[14];
[10]  Clip[ 3] := ModM[ 0]*ProjM[ 3] + ModM[ 1]*ProjM[ 7] +
                  ModM[ 2]*ProjM[11] + ModM[ 3]*ProjM[15];
[11]  Clip[ 4] := ModM[ 4]*ProjM[ 0] + ModM[ 5]*ProjM[ 4] +
                  ModM[ 6]*ProjM[ 8] + ModM[ 7]*ProjM[12];
[12]  Clip[ 5] := ModM[ 4]*ProjM[ 1] + ModM[ 5]*ProjM[ 5] +
                  ModM[ 6]*ProjM[ 9] + ModM[ 7]*ProjM[13];
[13]  Clip[ 6] := ModM[ 4]*ProjM[ 2] + ModM[ 5]*ProjM[ 6] +
                  ModM[ 6]*ProjM[10] + ModM[ 7]*ProjM[14];
[14]  Clip[ 7] := ModM[ 4]*ProjM[ 3] + ModM[ 5]*ProjM[ 7] +
                  ModM[ 6]*ProjM[11] + ModM[ 7]*ProjM[15];
[15]  Clip[ 8] := ModM[ 8]*ProjM[ 0] + ModM[ 9]*ProjM[ 4] +
                  ModM[10]*ProjM[ 8] + ModM[11]*ProjM[12];
[16]  Clip[ 9] := ModM[ 8]*ProjM[ 1] + ModM[ 9]*ProjM[ 5] +
                  ModM[10]*ProjM[ 9] + ModM[11]*ProjM[13];
[17]  Clip[10] := ModM[ 8]*ProjM[ 2] + ModM[ 9]*ProjM[ 6] +
                  ModM[10]*ProjM[10] + ModM[11]*ProjM[14];
[18]  Clip[11] := ModM[ 8]*ProjM[ 3] + ModM[ 9]*ProjM[ 7] +
                  ModM[10]*ProjM[11] + ModM[11]*ProjM[15];
[19]  Clip[12] := ModM[12]*ProjM[ 0] + ModM[13]*ProjM[ 4] +
                  ModM[14]*ProjM[ 8] + ModM[15]*ProjM[12];
[20]  Clip[13] := ModM[12]*ProjM[ 1] + ModM[13]*ProjM[ 5] +
                  ModM[14]*ProjM[ 9] + ModM[15]*ProjM[13];
[21]  Clip[14] := ModM[12]*ProjM[ 2] + ModM[13]*ProjM[ 6] +
                  ModM[14]*ProjM[10] + ModM[15]*ProjM[14];
[22]  Clip[15] := ModM[12]*ProjM[ 3] + ModM[13]*ProjM[ 7] +
                  ModM[14]*ProjM[11] + ModM[15]*ProjM[15];
.
.
.

In Zeile [05] extrahieren wir die momentane Projektionsmatrix und speichern sie in einem 16 Single-Werte enthaltendem Array, selbiges tun wir dann in Zeile [06] mit der aktuellen Modelbetrachtungsmatrix.
Diese beiden Matrizen werden dann in den Zeilen [07] bis [22] kombininert und werden als unsere Clippinmatrix gespeichert.

Die folgenden Zeilen berechnen nun endlich die sechs Flächen unserer Frustumbox.Die Namen der Flächen wurden vorher in der globalen Konstantensektion dieser Unit deklariert.

.
.
.
[23]  Frustum[Right][A] := clip[ 3] - clip[ 0];
[24]  Frustum[Right][B] := clip[ 7] - clip[ 4];
[25]  Frustum[Right][C] := clip[11] - clip[ 8];
[26]  Frustum[Right][D] := clip[15] - clip[12];
[27]  NormalizePlane(self, Right);

[28]  Frustum[Left][A] := clip[ 3] + clip[ 0];
[29]  Frustum[Left][B] := clip[ 7] + clip[ 4];
[30]  Frustum[Left][C] := clip[11] + clip[ 8];
[31]  Frustum[Left][D] := clip[15] + clip[12];
[32]  NormalizePlane(self, Left);

[33]  Frustum[Bottom][A] := clip[ 3] + clip[ 1];
[34]  Frustum[Bottom][B] := clip[ 7] + clip[ 5];
[35]  Frustum[Bottom][C] := clip[11] + clip[ 9];
[36]  Frustum[Bottom][D] := clip[15] + clip[13];
[37]  NormalizePlane(self, Bottom);

[38]  Frustum[Top][A] := clip[ 3] - clip[ 1];
[39]  Frustum[Top][B] := clip[ 7] - clip[ 5];
[40]  Frustum[Top][C] := clip[11] - clip[ 9];
[41]  Frustum[Top][D] := clip[15] - clip[13];
[42]  NormalizePlane(self, Top);

[43]  Frustum[Back][A] := clip[ 3] - clip[ 2];
[44]  Frustum[Back][B] := clip[ 7] - clip[ 6];
[45]  Frustum[Back][C] := clip[11] - clip[10];
[46]  Frustum[Back][D] := clip[15] - clip[14];
[47]  NormalizePlane(self, Back);

[48]  Frustum[Front][A] := clip[ 3] + clip[ 2];
[49]  Frustum[Front][B] := clip[ 7] + clip[ 6];
[50]  Frustum[Front][C] := clip[11] + clip[10];
[51]  Frustum[Front][D] := clip[15] + clip[14];
[52]  NormalizePlane(self, Front);
[53]  end;

Diese Berechnungen speichern ihr Ergebnis im Frustum-Array unserer TFrustum Klasse.Die Berechnung des Frustums muss nach jeder Blickwinkeländerung erfolgen.Wenn man zu faul ist, dies zu erfassen, kann man das Frustum auch einfach in jedem Frame nach dem setzen des Blickwinkels berechnen.

Punkt im Frustum?

Der einfachste Sichtbarkeitstest ist, festzustellen ob ein einzelner Punkt im Frustum liegt.Dies ist der Fall, wenn die Entfernung des Punktes zu allen sechs Flächen des Frustums positiv ist.(D.h. das der Punkt vor allen Flächen liegt.Ist die Entfernung negativ, so liegt er dahinter)

Um dies zu berechnen, nutzen wir folgende einfache Formel :

Distance := (A*x) + (B*y) + (C*z) + D

Die Funktion TFrustum.IsPointWithin(const pX, pY, pZ : Single) : Boolean durchläuft nun ganz einfache in einer Schleife alle sechs Flächen und berechnet die Entfernung des Punktes zu dieser Fläche.Wenn die Distanz negativ ist (der Punkt also dahinter liegt), liefert die Funktion False.

[01]  function TFrustum.IsPointWithin(const pX, pY, pZ : Single) : Boolean;
[02]  var
[03]   i : Integer;
[04]  begin
[05]  Result := true;
[06]  for i := 0 to 5 do
[07]   if (Frustum[i][A]*pX + Frustum[i][B]*pY +
           Frustum[i][C]*pZ + Frustum[i][D]) <= 0 then
[08]    begin
[09]    Result := False;
[10]    exit;
[11]    end;
[12]  end;

Kugel im Frustum?

Nachdem wir nun feststellen können, ob ein Punkt im Frustum liegt, ist selbiges mit einer Kugel ein Leichtes.Wie man wissen sollte, lässt sich eine Kugel durch zwei Attribute darstellen : Ihren Ursprungspunkt und ihren Radius.
Diese Funktion ersetzt also ganz einfach den Distanztest <=0 mit einem Distanztest gegen den negativen Radius der Kugel, also ziemlich einfach, oder?

[01]  function TFrustum.IsSphereWithin(const pX, pY, pZ,
                        pRadius : Single) : Boolean;
[02]  var
[03]   i : Integer;
[04]  begin
[05]  Result := true;
[06]  for i := 0 to 5 do
[07]   if (Frustum[i][A]*pX + Frustum[i][B]*pY +
           Frustum[i][C]*pZ + Frustum[i][D]) <= -pRadius then
[08]    begin
[09]    Result := False;
[10]    exit;
[11]    end;
[12]  end;

Dies ist der wohl meist genutzte Sichtbarkeitstest.Dies hat drei Gründe :
Erstens : Dieser Test ist der schnellste, da nur sechs Berechnungen anfallen.Zweitens : Die Begrenzung der meisten Objekte lassen sich als Kugel beschreiben.Drittens : Für eine Kugel wird nur der Speicherplatz von vier Single-Werten benötigt.
Wenn es also geht, sollte man diesen Test dem Quadertest vorziehen.

Quader im Frustum?

Festzustellen, ob sich ein Quader im Frustum befindet ist nicht viel schwerer als dies mit einer Kugel ist.Wie bekannt, besteht ein Quader aus acht Ecken.Also durchläuft die Funktion eine Schleife durch alle sechs Frustumflächen und prüft ob eine der Ecken vor einer der Flächen liegt.Ist dies der Fall, wird die Schleife unterbrochen.

[01]  function TFrustum.IsBoxWithin
        (const pX, pY, pZ, pB, pH, pT : Single) : Boolean;
[02]  var
[03]   i : Integer;
[04]  begin
[05]  Result := true;
[06]  for i := 0 to 5 do
[07]   begin
[08]   if (Frustum[i][A]*(pX-pB) + Frustum[i][B]*(pY-pH) +
           Frustum[i][C]*(pZ-pT) + Frustum[i][D]>0) then
[09]        continue;
[10]   if (Frustum[i][A]*(px+pB) + Frustum[i][B]*(py-pH) +
           Frustum[i][C]*(pz-pT) + Frustum[i][D]>0) then
[11]        continue;
[12]   if (Frustum[i][A]*(px-pB) + Frustum[i][B]*(py+pH) +
           Frustum[i][C]*(pz-pT) + Frustum[i][D]>0) then
[13]        continue;
[14]   if (Frustum[i][A]*(px+pB) + Frustum[i][B]*(py+pH) +
           Frustum[i][C]*(pz-pT) + Frustum[i][D]>0) then
[15]        continue;
[16]   if (Frustum[i][A]*(px-pB) + Frustum[i][B]*(py-pH) +
           Frustum[i][C]*(pz+pT) + Frustum[i][D]>0) then
[17]        continue;
[18]   if (Frustum[i][A]*(px+pB) + Frustum[i][B]*(py-pH) +
           Frustum[i][C]*(pz+pT) + Frustum[i][D]>0) then
[19]        continue;
[20]   if (Frustum[i][A]*(px-pB) + Frustum[i][B]*(py+pH) +
           Frustum[i][C]*(pz+pT) + Frustum[i][D]>0) then
[21]        continue;
[22]   if (Frustum[i][A]*(px+pB) + Frustum[i][B]*(py+pH) +
           Frustum[i][C]*(pz+pT) + Frustum[i][D]>0) then
[23]        continue;
[24]   Result := False;
[25]   end;
[26]  end;
[12]  end;

Wie vorher gesagt, benötigt dieser Test mehr Berechnungen als der Kugeltest(bis zu 48).Wenn man also eine Kugel statt eines Quaders als Begrenzung für ein Objekt nutzen kann, sollte man das tun.Dies spart jede Menge Berechnungen.

Das Beispielprogramm

Das Beispielprogramm rendert jede Menge Kugeln und prüft deren Sichtbarkeit via Frustum Culling bevor diese zur Grafikkarte gesendet werden.Mit Hilfe des Buttons kann das Frustum Culling ein- bzw. ausgeschaltet werden, um den Geschwindigkeitsunterschied leichter zu erkennen.

Download

Das Frustum-Culling Demo (inklusive Quellcode) herunterladen

Letzte Aktualisierung : 18.06.2004